Anthony, below is a handy utility I use a lot (ported to VB) to test
file sharing:
--------- Cut Here save in testfileblock.vb ----
' File: TestFileLock.vb
Option Strict on
Option Explicit On
imports system
imports system.console
imports system.io
Module module1
Function log(Fmt As String, ParamArray args() As Object) As Integer
Writeline(fmt,args)
End Function
sub main(ByVal args() As String)
if (args.length = 0 orElse Array.IndexOf(Args,"/?") > -1) then
log("usage: testfilelock filename [access:mode] [share:mode]")
log("")
log("opens existing filename with access and share modes.")
log("")
log("access:mode where mode is:")
log(" r open for reading")
log(" w open for writing")
log(" rw open for reading & writing")
log("")
log("share:mode where mode is:")
log(" r allow others to open for reading")
log(" w allow others to open for writing")
log(" rw allow others to open for reading/writing")
log("")
log("examples:")
log("")
log(" testfilelock c:\test1 access:r share:rw")
log(" testfilelock c:\test1 access:rw")
log("")
exit sub
end if
dim fname as string = args(0)
dim omode as FileMode = FileMode.Open
dim amode as FileAccess = FileAccess.Read
dim smode as FileShare = FileShare.None
for i as integer = 1 to Args.Length-1
dim tmode as string() = args(i).tolower.split(":"c)
if (tmode(0) = "access") then
select case(tmode(1))
case "r" : amode = FileAccess.Read
case "w" : amode = FileAccess.Write
case "rw" : amode = FileAccess.ReadWrite
end select
elseif (tmode(0) = "share") then
select case(tmode(1))
case "r" : smode = FileShare.Read
case "w" : smode = FileShare.Write
case "rw" : smode = FileShare.ReadWrite
end select
end if
next
try
Dim sr As FileStream = File.Open(fname, omode, amode, smode)
log("* File {0} open with access: {1} share: {2}",fname,
amode, smode)
log("- Press ANY KEY to close file")
ReadKey(true)
sr.close()
catch ex as exception
log("! OPEN FILE ERROR: "+ex.Message)
finally
end try
end sub
end Module
--------- Cut Here ----
Usage:
TestFileLock C:\MYFILENAME open:read share:read
The above is the same open/share mode as File.Open(). To repeat the
sharing error, lock it like so:
TestFileLock C:\MYFILENAME open:read
then run your application. It should give you the same error like you
got.
--
Well, in lieu of some other CPLE (Classic Programmer Logic Error) or
.NET network file security system, I seriously doubt there are
differences in the FILE I/O sharing logic in any OS or .NET framework.
FILE I/O is so COMMON in the interoperability of file management across
all networks and OS, that to guess this File Sharing Error is related to
.NET versions (again outside of security), it just will break many things.
The point is that I can lock a file in any LANGUAGE and .NET
System.IO.FILE class better behave correctly or it will be a show
stopper for many product lines and operations.
So focus on the CPLE <g>
If you can reduce it to:
dim sr as streamreader = nothing
try
sr = File.OpenText("somefile")
catch ex as exception
console.writeline(ex.message)
end try
and repeat the file sharing error over and over again, then you have a
CPLE somewhere. Nothing to do with the OS or framework version. You
would be wasting a lot of time focusing on that.
According to MSDN, OpenText opens the file in
Open Mode = READ
Share Mode = READ
That means at the lowest levels, the win32 function:
handle = CreateFile(filename,
GENERIC_READ
FILE_SHARE_READ,,,)
The only way possible to get a sharing violation error is when another
process or thread in the same process owns an open handle to the file
with the following share modes:
1) SHARE = WRITE but NO SHARE = READ
2) Has SHARE = NOTHING (0)
Those are the rules. It so fundamental to the file I/O sharing in all
DOS, Windows, UNIX, MAC OSes, it ain't funny.
Me thinks you have a different issue. What is the name of the source
file you are trying to open? Didn't you say Process Explorer showed the
file is open. Well, is it suppose to be?
