worksheet

[Guest]

How do I add a path and filename to a worksheet?

 

[DDM]

Vernelle, you'll find the answer here:
http://www.cpearson.com/excel/excelF.htm#FileName.

DDM
"DDM's Microsoft Office Tips and Tricks"
www.ddmcomputing.com

 

[Guest]

thank you ddm

 

[Gord Dibben]

Vernelle

Assuming in a cell. If somewhere else, please post back.

From a post by Chip Pearson............

Use
=CELL("filename",A1)
to get the full name, including the sheet name. E.g.,
C:\Temp\[Test.Xls]Sheet1

Use
=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,LEN(CELL("filename"
,A1))-FIND("]",CELL("filename",A1)))
to get just the sheet name
Sheet1


Use
=MID(CELL("filename",A1),FIND("[",CELL("filename",A1))+1,FIND("]",CELL("file
name",A1))-FIND("[",CELL("filename",A1))-1)
to get just the file name
Test.Xls

Use
=LEFT(CELL("filename",A1),FIND("]",CELL("filename",A1)))
to get full name without sheet name
C:\Temp\[Test.xls]

Use
=SUBSTITUTE(SUBSTITUTE(LEFT(CELL("filename",A1),FIND("]",CELL("filename",A1)
)),"[",""),"]","")
to get full name without sheet name, and without square brackets
C:\Temp\Test.Xls


Gord Dibben Excel MVP