vlookup on 3 different tables - please HELP

  • Thread starter Thread starter Guest
  • Start date Start date
G

Guest

Hi
I have a value that can be found in coulmn A of 3 different tables, i would
like to perform the lookup on the 3 tables. can it be done without unifying
the tables?

thanks
 
can or may
if you mean it might be in table 1 and stop use something like

=VLOOKUP(C1,IF(ISNA(VLOOKUP(C1,tab1,2,0)),tab2,tab1),2,0)

Don Guillett
SalesAid Software
(e-mail address removed)
 
=IF(ISNA(VLOOKUP(value,table1,2,FALSE)),IF(ISNA(VLOOKUP(value,table2,2,FALSE
)),
IF(ISNA(VLOOKUP(value,table3,2,FALSE)),"Not found",
VLOOKUP(value,table3,2,FALSE)),VLOOKUP(value,table2,2,FALSE)),VLOOKUP(value,
table1,2,FALSE))

--
HTH

Bob Phillips

(replace somewhere in email address with gmail if mailing direct)
 
If the free add-in Morefunc.xll is downloaded and installed, then
something like the following formula can be used...

=VLOOKUP(B2,THREED('Sheet1:Sheet3'!$A$2:$B$100),2,0)

Alternatively, let A2:A4 contain the sheet names, then try the following
formula which needs to be confirmed with CONTROL+SHIFT+ENTER, not just
ENTER...

=VLOOKUP(B2,INDIRECT("'"&INDEX($A$2:$A$4,MATCH(TRUE,COUNTIF(INDIRECT("'"&
$A$2:$A$4&"'!A2:A100"),B2)>0,0))&"'!A2:B100"),2,0)

The add-in can be downloaded here...

http://xcell05.free.fr/

Hope this helps!
 
Back
Top