USING "IF" STATEMENTS FOR MONTHS OF YEAR(IF 1=JANUARY)

[Tina]

I Have the following if statement in my excel spreadhseet. the only problem
is that I cannot finish out the year with Sept.-Dec. (I get an error that
says the statement is too big) What can I do to make this formula work for
the whole year??

=IF(Date!D2=1,"JAN.",IF(Date!D2=2,"FEB.",IF(Date!D2=3,"MAR.",IF(Date!D2=4,"APR.",
IF(Date!D2=5,"MAY",IF(Date!D2=6,"JUN.",IF(Date!D2=7,"JUL.",IF(Date!D2=8,"AUG."))))))))

 

[Bob Phillips]

Try

=UPPER(TEVALUE("01-"&D2),"mmm"))

HTH

Bob

 

[Dave Peterson]

=IF(Date!D2="","",TEXT(DATE(2000,Date!D2,1),"mmm")&".")

 

[David Biddulph]

Either change to excel 2007, or use
=UPPER(TEXT(DATE(1900,Date!D2,1),"mmm"))&"."

 

[Eva]

Hi
Do you have a date there? If the answer is yes I have simple formula
=TEXT(A1,"mmmm") (if in A1 is a date)
click yes if helped

 

[Bob Phillips]

Got manged a bit, should have been

=UPPER(TEXT(VALUE("01-"&D2),"mmm"))

HTH

Bob

 

[Rick Rothstein]

One more for you to try...

=UPPER(TEXT(28*D2,"mmm"))