Text Import Wizard (use for large files)

[Guest]

I've got a text file that I am attempting to import (over 65500 lines) and of
course I'm getting the alert for the size limit for one worksheet. However,
Excel does prompt me with the following message. Can someone give me a quick
description of how to rerun the import on another tab and EXCLUDE the
previous data? I've attempted this but it seems to just import the same
data. I've looked in the options for some sort of setting, but have not
found anything useful.
Thanks in advance...

"The text file contains more data than will fit on a single worksheet.
To continue and import as much of the dta as will fit, click OK. You can
then import the rest of the data by repeating the import operation on another
worksheet and using the Text Import Wizard to exclude data already imported."

 

[Niek Otten]

Not sure what you're after, but just in case:

' ===========================================================
' Importing a large file into Excel. File MAY have more than 65,000 records
' and will automatically start a new sheet.


Sub LargeFileImport()
'Bernie Deitrick's code for opening very large text files in Excel
'Dimension Variables
Dim ResultStr As String
Dim FileName As String
Dim FileNum As Integer
Dim Counter As Double
'Ask User for File's Name
FileName = Application.GetOpenFilename
'Check for no entry
If FileName = "" Then End
'Get Next Available File Handle Number
FileNum = FreeFile()
'Open Text File For Input
Open FileName For Input As #FileNum
'Turn Screen Updating Off
Application.ScreenUpdating = False
'Create A New WorkBook With One Worksheet In It
Workbooks.Add Template:=xlWorksheet
'Set The Counter to 1
Counter = 1
'Loop Until the End Of File Is Reached
Do While Seek(FileNum) <= LOF(FileNum)
'Display Importing Row Number On Status Bar
Application.StatusBar = "Importing Row " & Counter & " of text file " _
& FileName
'Store One Line Of Text From File To Variable
Line Input #FileNum, ResultStr
'Store Variable Data Into Active Cell
If Left(ResultStr, 1) = "=" Then
ActiveCell.Value = "'" & ResultStr
Else
ActiveCell.Value = ResultStr
End If
If ActiveCell.Row = 65536 Then
'If On The Last Row Then Add A New Sheet
ActiveWorkbook.Sheets.Add
Else
'If Not The Last Row Then Go One Cell Down
ActiveCell.Offset(1, 0).Select
End If
'Increment the Counter By 1
Counter = Counter + 1
'Start Again At Top Of 'Do While' Statement
Loop
'Close The Open Text File
Close
'Remove Message From Status Bar
Application.StatusBar = False
End Sub

' ===========================================================


--
Kind regards,

Niek Otten
Microsoft MVP - Excel



| I've got a text file that I am attempting to import (over 65500 lines) and of
| course I'm getting the alert for the size limit for one worksheet. However,
| Excel does prompt me with the following message. Can someone give me a quick
| description of how to rerun the import on another tab and EXCLUDE the
| previous data? I've attempted this but it seems to just import the same
| data. I've looked in the options for some sort of setting, but have not
| found anything useful.
| Thanks in advance...
|
| "The text file contains more data than will fit on a single worksheet.
| To continue and import as much of the dta as will fit, click OK. You can
| then import the rest of the data by repeating the import operation on another
| worksheet and using the Text Import Wizard to exclude data already imported."

 

[Jim Cone]

This gives an explanation and the way to import up to 98000 rows.
Look at the XL97 section near the bottom...
http://support.microsoft.com/?kbid=119770
"Text Import Wizard..."
--
Jim Cone
San Francisco, USA
http://www.realezsites.com/bus/primitivesoftware




"Traci" <[email protected]>
wrote in message
I've got a text file that I am attempting to import (over 65500 lines) and of
course I'm getting the alert for the size limit for one worksheet. However,
Excel does prompt me with the following message. Can someone give me a quick
description of how to rerun the import on another tab and EXCLUDE the
previous data? I've attempted this but it seems to just import the same
data. I've looked in the options for some sort of setting, but have not
found anything useful.
Thanks in advance...

"The text file contains more data than will fit on a single worksheet.
To continue and import as much of the dta as will fit, click OK. You can
then import the rest of the data by repeating the import operation on another
worksheet and using the Text Import Wizard to exclude data already imported."