Problem with date format

[Benedikt Friðbjörnsson]

Hi Can anyone help me with this code. The problem is that in my country the
date format is dd.mm.yyyy. When I run this code is I get "Syntax error in
date in query expression '([MyDate] >= #3.11.2008#'. When I change the
format in my computer to dd/mm/yyyy the code is OK.

best regards
Benedikt
IT Samherji
Iceland


Option Compare Database
Option Explicit

Private Sub cmdApplyFilter_Click()
Dim strFilter As String
Dim blnFilterOn As Boolean
Dim strCriteria As String

strCriteria = "Criteria: "

If Nz(Me.cboNName, vbNullString) <> vbNullString Then
strFilter = " AND [NName] = '" & Me.cboNName & "'"
strCriteria = strCriteria & "Name = " & cboNName
End If

If Nz(Me.txtStartDate, vbNullString) <> vbNullString And
Nz(Me.txtEndDate, vbNullString) <> vbNullString Then
If Me.txtStartDate > Me.txtEndDate Then
MsgBox "Start Date Cannot Be Greater Than End Date",
vbInformation
Exit Sub
End If
End If
If Nz(Me.txtStartDate, vbNullString) <> vbNullString Then
strFilter = strFilter & " AND [MyDate] >= #" & Me.txtStartDate & "#"
strCriteria = strCriteria & vbCrLf & "Begin Date: " &
Me.txtStartDate
End If

If Nz(Me.txtEndDate, vbNullString) <> vbNullString Then
strFilter = strFilter & " AND [MyDate] <= #" & Me.txtEndDate & "#"
strCriteria = strCriteria & vbCrLf & "End Date: " & Me.txtEndDate
End If

If strFilter <> vbNullString Then
strFilter = Mid(strFilter, 6)
Me.txtCriteria = strCriteria
Reports("rptForPopUp").Filter = strFilter
Reports("rptForPopUp").FilterOn = True
Else
MsgBox "Enter some criteria", vbInformation
End If


End Sub

 

[Scott Lichtenberg]

Benedikt

Access requires American format dates in SQL statements.
strFilter = strFilter & " AND [MyDate] >= #" & Format(Me.txtStartDate,
"mm/dd/yyyy") & "#"

Take a look at this link. http://allenbrowne.com/ser-36.html#Format



=======